_bunsen-init:
    #!/bin/bash

    if ! [ -d $HOME/.local/share/pdm/venvs/*-bunsen ]; then
        pdm venv create -n bunsen --with-pip cpython@3.12;

        VENV_ROOT=$(pdm venv --path bunsen)
        $(pdm venv activate bunsen)

        cd {{ BUNSEN_SRC_ROOT }}
        pip install -r requirements.txt
        pip install lxml
        ./configure --prefix=$VENV_ROOT
        make
        make install
    fi

    [ -d testruns ] || git init testruns


bunsen CMD *ARGS: _bunsen-init
    #!/bin/bash

    $(pdm venv activate bunsen); {{CMD}} --git {{ justfile_directory() }}/testruns --db {{ justfile_directory() }}/testruns/bunsen.sqlite3 {{ARGS}}


http-testresults: _bunsen-init
    #!/bin/bash

    $(pdm venv activate bunsen)
    r-httpd-browse --bind 0.0.0.0 --git {{ justfile_directory() }}/testruns --db {{ justfile_directory() }}/testruns/bunsen.sqlite3


# List all tags in repo
ls-testruns: _bunsen-init
    # git -C {{ justfile_directory() }}/testruns log --all --pretty=format:"%C(yellow)%H%C(bold)%d"
    git -C {{ justfile_directory() }}/testruns tag --list --format='%(refname:short) %(objectname)'


ls-testsuites RUN: _bunsen-init
    #!/bin/bash

    $(pdm venv activate bunsen)
    r-show-testrun --git {{ justfile_directory() }}/testruns \
        --db {{ justfile_directory() }}/testruns/bunsen.sqlite3 {{RUN}} \
        --dejagnu --template json | jq '.dgtestsuites | keys | .[]'


ls-testresults RUN SUITE: _bunsen-init
    #!/bin/bash

    $(pdm venv activate bunsen)
    r-show-testrun --git {{ justfile_directory() }}/testruns --db {{ justfile_directory() }}/testruns/bunsen.sqlite3 \
        {{RUN}} --dgexpfile '{{SUITE}}'


# Only works with test-gcc recipe.
add-testrun BASENAME BASEDIR="build-gcc/gcc": _bunsen-init
    #!/bin/bash

    $(pdm venv activate bunsen)
    t-upload-git-push {{ justfile_directory() }}/testruns {{BASENAME}}-{{ datetime('%Y-%m-%dT%H.%M.%S') }} {{BASEDIR}}/testsuite.{{BOARD}}.{{ replace(MULTILIB, '/', '.') }}/{gcc/gcc,g++/g++}.{log,sum}


alias pl := pipeline-testruns

pipeline-testruns: _bunsen-init
    #!/bin/bash

    $(pdm venv activate bunsen)
    pipeline --git {{ justfile_directory() }}/testruns --db {{ justfile_directory() }}/testruns/bunsen.sqlite3


diff-testruns OLD NEW *ARGS: _bunsen-init
    #!/bin/bash

    $(pdm venv activate bunsen)
    r-diff-testruns --git {{ justfile_directory() }}/testruns --db {{ justfile_directory() }}/testruns/bunsen.sqlite3 {{ARGS}} {{OLD}} {{NEW}}