define pfifo
  while(((USB_OTG_GlobalTypeDef *) $usb_base)->GINTSTS & 0x10)
    out/xz ((USB_OTG_GlobalTypeDef *) $usb_base)->GRXSTSP
    echo \n
  end
end

define pfifod
  set $n = 0
  while($n < 320)
    printf "%d: ", $n
    out/xz (* (uint32_t *) ($usb_base + 0x20000 + 4*$n))
    echo \n
    set $n = $n + 1
  end
end

define pglb
  out/xz * (USB_OTG_GlobalTypeDef *) $usb_base
end

define pdev
  out/xz * (USB_OTG_DeviceTypeDef *) ($usb_base + 0x800U)
end

define pin
  out/xz * ((USB_OTG_INEndpointTypeDef *) ($usb_base + 0x900U) + $arg0)
end

define pout
  out/xz * ((USB_OTG_OUTEndpointTypeDef *) ($usb_base + 0xB00U) + $arg0)
end

#define ppll
#  p/xz * (uint32_t *) (0x58024400 + 0x30)
#end

#define ppllr
#  p/xz * (uint32_t *) (0x58024400 + 0x2c)
#end

define pusb-generic
  set $n = 0
  echo GLB:\n
  pglb
  echo \nDEV:\n
  pdev

  while $n < $arg0
    printf "\nIN %d:\n", $n
    pin $n
    set $n = $n + 1
  end

  set $n = 0
  while $n < $arg0
    printf "\nOUT %d:\n", $n
    pout $n
    set $n = $n + 1
  end

  echo \n
end